excel表格_excel函数公式大全_execl从入门到精通
转置，在数据查询中的利用方法2024-04-25 17:20:46
大家好,今日继续讲解VBA数据库解决方案,今日讲解的是第72讲,内容是:转置函数在查询中的利用。数据处理的结果是要形成一个比较好看易懂的报表，如何能做出我们需要的格式，这就要我们灵活的运用所学到的知识,大胆的进行尝试。今天讲的是转置函数，这个函数在数组中经常的用到，我们看看在数据库中，这个函数是怎么利用的 。
实例,如下的工作表中数据,我们要形成一个汇总的表格, 这个汇总的表格中含有姓名,和每个人的销售总额,
同时我们要从数据中反馈出每个人每个月的销售情况,也就是说还要把日期B列转换为记录集的字段进行汇总,如何实现这个功能呢?这就要用到转置函数了.下面先看我的代码,然后我会在讲解中给大家讲到.
Sub mynzRecords_72() '第72讲 查询后的汇总与转置
Dim cnADO, rsADO As Object
Dim strPath, strSQL As String
Worksheets("72").Select
Cells.ClearContents
Set cnADO = CreateObject("ADODB.Connection")
Set rsADO = CreateObject("ADODB.Recordset")
strPath = ThisWorkbook.FullName
cnADO.Open "provider=Microsoft.ACE.OLEDB.12.0;extended properties='excel 12.0;hdr=yes;imex=1';" _
& "data source=" & strPath
'建立起一个转置的查询
strSQL = "TRANSFORM SUM(销售额) SELECT 姓名,SUM(销售额) AS 合计 " _
& "FROM [数据6$] GROUP BY 姓名 PIVOT FORMAT(日期,'mm月')"
'打开记录集
rsADO.Open strSQL, cnADO, 1, 3
For i = 1 To rsADO.Fields.Count
Cells(1, i) = rsADO.Fields(i - 1).Name
Next
'提出数据
Range("a2").CopyFromRecordset rsADO
'释放内存
rsADO.Close
cnADO.Close
Set rsADO = Nothing
Set cnADO = Nothing
End Sub
代码截图：代码讲解：
1 上述代码将完成一个转置的查询结果，将月份的值作为字段来进行分类。
2 strSQL = "TRANSFORM SUM(销售额) SELECT 姓名,SUM(销售额) AS 合计 " _
& "FROM [数据6$] GROUP BY 姓名 PIVOT FORMAT(日期,'mm月')"
这句的代码是利用一个转置函数TRANSFORM+ PIVOT的格式来实现我们的要求。
所谓转置函数，即TRANSFORM...PIVOT... 语句，这是Microsoft JET Engine 3.5以上版本所特有的SQL查询语句，该语句的特点是可以建立一个交叉表格式的查询。该语句可以将表中的某些数据作为行，某些数据作为列建立交叉表。
该语句的语法如下：
TRANSFORM condition [select opreation] PIVOT column
特别注意点：
① TRANSFORM和Pivot后面都只能有一个字段。
② condition是在交叉表中要显示的数据，select opreation 是一个SELECT...FROM... 查询，该查询形成交叉表的行信息，PIVOT中column为表中的一个字段，PIVOT语句使用该字段形成交叉表的列。
③ 上面的格式用另外的表达方式为：Transfrom 数据区域 select 行字段 from (数据源) group by 分组依据 pivot 列字段
下面看代码的运行结果：今日内容回向：
1 转置函数在什么情况下应用？
2 转置函数的语法是什么样的？
标签: excel如何做交叉表